//---------------------------------------------------------------------------
//
//       ASSERT_ONE_HOT
//
//---------------------------------------------------------------------------
// NAME
//          ASSERT_ONE_HOT - An invariant concurrent assertion to ensure 
//                           that only one bit of a variable is active high.
//
//---------------------------------------------------------------------------
module assert_one_hot (clk, reset_n, test_expr);
// synopsys template
  parameter severity_level = 0;
  parameter width=32;
`ifdef ASSERT_V1_0_1 	// Previous version of the library
`else			// New version to allow for future options
  parameter options = 0;
`endif
  parameter msg="VIOLATION";
  input clk, reset_n;
  input [width-1:0] test_expr;

//synopsys translate_off
`ifdef ASSERT_ON
  wire [width-1:0] test_expr_1 = test_expr - {{width-1{1'b0}},1'b1};

  parameter assert_name = "ASSERT_ONE_HOT";

  integer error_count;
  initial error_count = 0;

  `include "ovl_task.h"

  `ifdef ASSERT_INIT_MSG
    initial
      ovl_init_msg; // Call the User Defined Init Message Routine
  `endif

  always @(posedge clk) begin
    `ifdef ASSERT_GLOBAL_RESET
      if (`ASSERT_GLOBAL_RESET != 1'b0) begin
    `else      
      if (reset_n != 1'b0) begin
    `endif
        if ((test_expr ^ test_expr)==0) begin
          if ((test_expr == {width{1'b0}}) ||
              (test_expr & test_expr_1) != {width{1'b0}}) begin
            ovl_error("");
          end
        end
        else begin
          ovl_error("Error: test_expr contains X/Z value");
        end
      end
   end // always

`endif
//synopsys translate_on

endmodule