//---------------------------------------------------------------------------
//
//        ASSERT_NO_OVERFLOW
//
//---------------------------------------------------------------------------
// NAME
//          ASSERT_NO_OVERFLOW - An invariant concurrent assertion to ensure
//                      an expression (or variable) does not exceed
//                      a MAX value or reach a value <= MIN limit.
//
//---------------------------------------------------------------------------
module assert_no_overflow (clk, reset_n, test_expr);
// synopsys template
  parameter severity_level = 0;
  parameter width=1;
  parameter min=0;
  parameter max= ((1<<width)-1);
`ifdef ASSERT_V1_0_1 	// Previous version of the library
`else			// New version to allow for future options
  parameter options = 0;
`endif
  parameter msg="VIOLATION";
  input clk, reset_n;
  input [width-1:0] test_expr;

//synopsys translate_off
`ifdef ASSERT_ON

  // local paramaters used as defines
  parameter OVERFLOW_START = 1'b0;
  parameter OVERFLOW_CHECK = 1'b1;

  reg r_state;
  initial r_state=OVERFLOW_START;

  parameter assert_name = "ASSERT_NO_OVERFLOW";

  integer error_count;
  initial error_count = 0;

  `include "ovl_task.h"

  `ifdef ASSERT_INIT_MSG
    initial
      ovl_init_msg; // Call the User Defined Init Message Routine
  `endif

  always @(posedge clk) begin
    `ifdef ASSERT_GLOBAL_RESET
      if (`ASSERT_GLOBAL_RESET != 1'b0) begin
    `else      
      if (reset_n != 0) begin  // active low reset
    `endif
        case (r_state)
          OVERFLOW_START:
            if (test_expr == max) begin
               r_state <= OVERFLOW_CHECK;
            end
          OVERFLOW_CHECK:
            if (test_expr != max) begin
              r_state <= OVERFLOW_START;
              if (test_expr <= min || test_expr > max) begin
                ovl_error("");
              end
            end
        endcase
      end
      else begin
        r_state <= OVERFLOW_START;
      end
  end // always

`endif
//synopsys translate_on

endmodule