//---------------------------------------------------------------------------
//
//       ASSERT_NEVER
//
//---------------------------------------------------------------------------
// NAME
//          ASSERT_NEVER - An invariant concurrent assertion to ensure 
//                that its argument never evaluates TRUE.
//
//---------------------------------------------------------------------------
module assert_never (clk, reset_n, test_expr);
// synopsys template
  input clk, reset_n, test_expr;
  parameter severity_level = 0;
`ifdef ASSERT_V1_0_1 	// Previous version of the library
`else			// New version to allow for future options
  parameter options = 0;
`endif
  parameter msg="VIOLATION";

//synopsys translate_off
`ifdef ASSERT_ON

  parameter assert_name = "ASSERT_NEVER";

  integer error_count;
  initial error_count = 0;

  `include "ovl_task.h"

  `ifdef ASSERT_INIT_MSG
    initial
      ovl_init_msg; // Call the User Defined Init Message Routine
  `endif

  always @(posedge clk) begin
    `ifdef ASSERT_GLOBAL_RESET
      if (`ASSERT_GLOBAL_RESET != 1'b0) begin
    `else      
      if (reset_n != 1'b0) begin
    `endif
        if (test_expr  != 1'b0) begin
          ovl_error("");
        end
      end
  end // always

`endif
//synopsys translate_on

endmodule