//---------------------------------------------------------------------------
//
//       ASSERT_ALWAYS
//
//---------------------------------------------------------------------------
// NAME
//          ASSERT_ALWAYS - An invariant concurrent assertion to ensure 
//                            its argument always evaluates TRUE 
//
//---------------------------------------------------------------------------

module assert_always (clk, reset_n, test_expr);
// synopsys template
  parameter severity_level = 0;
`ifdef ASSERT_V1_0_1 	// Previous version of the library
`else			// New version to allow for future options
  parameter options = 0;
`endif
  parameter msg="VIOLATION";
  input clk, reset_n, test_expr;

//synopsys translate_off
`ifdef ASSERT_ON

  parameter assert_name = "ASSERT_ALWAYS";

  integer error_count;
  initial error_count = 0;

  `include "ovl_task.h"

  `ifdef ASSERT_INIT_MSG
    initial
      ovl_init_msg; // Call the User Defined Init Message Routine
  `endif

  always @(posedge clk) begin
    `ifdef ASSERT_GLOBAL_RESET
      if (`ASSERT_GLOBAL_RESET != 1'b0) begin
    `else      
      if (reset_n != 0) begin  // active low reset
    `endif
        if (test_expr  != 1'b1) begin
          ovl_error("");
        end
      end
  end
`endif
//synopsys translate_on

endmodule